Лабораторная работа № 6

Тема: Обработка частотных и временных сигналов

Цель работы: Изучение методов частотного преобразования

Учебная задача: Научиться осуществлять измерение частоты, периода, длительность дискретных сигналов с помощью программируемых счетчиков/ таймеров ОЭВМ 1816 ВЕ31, а также с использованием внешнего эталонного генератора.

Порядок выполнения лабораторной работы.

1) Изучить методы частотного преобразования (аппаратные и с помощью программируемых счетчиков таймеров)

2) Изучить методы измерения временных интервалов.

3) Разработать алгоритм для выполнения индивидуального задания до начало лабораторного занятия.

4) Разработать программу для выполнения индивидуального задания до начало лабораторного занятия

5) Ввести программу индивидуального задания на персональном компьютере.

6) С помощью ПОС проанализировать выполнение индивидуальной программы

7) Загрузить программу в стенд ОЭВМ. Убедиться в правильном выполнении индивидуального задания, изменить значение измеряемой частоты, повторить преобразование, при отрицательном результате осуществить изменение алгоритма либо программы.

8) Распечатать листинг правильно работающей программы.

9) Ответить на контрольные вопросы преподавателя

Контрольные вопросы.

1. Методы и типы частотного и временного преобразования.

2. Параметры частотного преобразования.

3. Факторы влияющие на погрешность частотного преобразования.

4. Понятие разрешающая способность частотного преобразования.

5. Измерение периода.

6. Характеристика преобразования, нелинейность частотного преобразования.

7. Аппаратные реализации частотного и временного преобразования.

8. Примеры практического применения частотного и временного преобразования

Краткие теоретические сведения

В системах автоматического управления часто приходится измерять такие величины как: частота f, период T, длительность t, сдвиг фаз j. Для этого применяется преобразование частота-код. В зависимости от того, какой именно параметр нужно измерить применяют разный подход.

Рисунок 11.

При измерении частоты f x производится счет импульсов входного сигнала, в течении фиксированного отрезка времени рис11.

Рисунок 12. Измерение периода следования методом подсчета количества импульсов известной частоты.

Такой метод приемлем для измерения высоких частот больше 100Гц. Верхний предел ограничивается быстродействием элементов схемы и разрядностью счетчиков.

Рисунок 13. Измерение сдвига фаз

Измерение частот ниже 100Гц заменяется измерением периода Т х. При этом производится подсчет импульсов фиксированной частоты f₀ за интервал равный или кратный измеряемому периоду рис.12.

Таким же образом измеряется длительность импульса t _х, отличие состоит лишь в том, что при измерении длительности импульса ненужно делить частоту на два.

При измерении сдвига фаз временной интервал t_j формируют путем конъюнкции сигналов f₁ x и f₂ x рис.13, полученный интервал времени измеряют методом описанным выше.

Схемы, реализующие такой алгоритм, приведены на рисунке 14.

Рисунок 14. Схемы для измерения частоты а) низкой, б) высокой

В лабораторном стенде при наличии платы расширения к входу ОЭВМ Т0 подключен постоянный генератор частоты, а к входу Т1 подключен генератор с изменяемой частотой. Сигналы этих генераторов можно наблюдать на осциллографе, подключенном к BNC разъему. Для наблюдения сигнала Т0 замкнуть перемычку J1, а для Т1 перемычку J3

Таймеры/счетчики (Т/С) ОЭВМ предназначены для подсчета внешних событий, для получения программно управляемых временных задержек, выполнения времязадающих функций ОЭВМ.

В состав блока Т/С входят:

1) два 16-ти разрядных регистра Т/С 0, Т/С 1;

2) 8-ми разрядный регистр режимов Т/С (ТМ0D);

3) 8-ми разрядный регистр управления (ТСОN);

4) схема инкремента; ____ ____

5) схема фиксации INT0, INT1, Т0, Т1;

6) схема управления флагами;

7) логика управления Т/С.

Два 16-разрядных регистра Т/С 0 и Т/С 1 выполняют функцию хранения содержимого счета. Каждый из них состоит из пары 8-ми разрядных регистров, соответственно ТH0, ТL0 и ТH1, ТL1. Причем регистры ТН0, ТH1 - старшие, регистры ТL0, ТL1 - младшие 8 разрядов. Каждый из 8-ми разрядных регистров может быть использован, как РОН, если Т/С не используются (бит TR0 для Т/С 0 и бит TR1 для Т/С 1 в регистре управления TCON равен " 0").

Регистр режимов Т/С (TMOD) предназначен для приема и хранения кода, определяющего:

- один из 4-х возможных режимов работы каждого Т/С;

- работу в качестве таймеров или счетчиков;

- управление Т/С от внешнего вывода.

Регистр режимов TMOD

M0-M1(0-1, 4-5) – один из 4-х режимов счётчиков

С/Т(2, 6) – ’0’ таймер ’1’ счётчик

GATE – разрешение управления от внешнего вывода ’0’ запрещено ’1’ разрешено(INT0, INT1)

Регистр управления (TCON) предназначен для приема и хранения кода управляющего слова. Регистр TCON нельзя использовать в качестве РОН. Схема инкремента предназначена для увеличения на 1 в каждом машинном цикле содержимого регистров Т/С 0, Т/С 1, для которых:

- установлен режим таймера и счет разрешен;

- установлен режим счетчика, счет разрешен и на соответствующем входе схемы Т0 (для Т/С 0) или Т1 (для Т/С 1) зафиксирован счетный импульс в предыдущем машинном цикле.

Регистр управления TCON

TR – бит включения Т/C ’0’ выключен

TF – флаг переполнения Т/C

IT – определяет вид прерывания по входу INT ’0’ по L-уровню, ’1’ по фронту

IE – флаг запроса на прерывание

Пример программы измерения частоты

$nolist

$include(c: \asm51\compile\mod51)

$list

; измерение частоты в Гц

; рассчитана на внешнюю частоту Т0 6817Гц

; подсчет ведется за 1с, результат в виде ХХХХ Гц

mode equ 55h; настраивает T1 counter, T0 counter

str equ 50h; запись в TCON разрешает счет

ORG 0000h

BEG: MOV TL1, #00h; обнуление

MOV TH1, #00h; Т/С1

MOV TL0, #0f0h; предустановка Т/С0

MOV TH0, #0E4h; рассчитана на 1с

MOV TMOD, #MODE; инициализация режимов таймеров

MOV TCON, #STR; запуск счета

JNB TF0, $; проверка флага переполнения Т/С0

CLR TR1; если произошло переполнение то

CLR TR0; остановить счет Т/С1 и Т/С0

MOV R0, TL1; считывание результата измерения

MOV R1, TH1; R0 содержит младшую часть а R1 старшую

CALL IND; вызов подпрограммы индикации

MOV R3, #01h; временная задержка

M: MOV R4, #01h; на двух регистрах

DJNZ R4, $; с декрементом

DJNZ R3, M; во вложенном цикле

JMP BEG; переход на следующий цикл измерения

IND:; подпрограмма индикации, производит перевод результата

; из двоичной системы в двоично-десятичную

; и отображение

JMP M1

L: DB 01h, 02h, 04h, 08h, 16h, 32h, 64h, 28h, 56h, 12h, 24h, 48h, 96h

HI: DB 00h, 00h, 00h, 00h, 00h, 00h, 00h, 01h, 02h, 05h, 10h, 20h, 40h

M1: MOV R2, #00h

MOV R6, #00h

MOV R7, #00h

NACHALO_L: MOV A, R0

JNB ACC.0, AGAIN_L

MOV A, R2

MOV DPTR, #L

MOVC A, @A+DPTR

ADD A, R6

DA A

MOV R6, A

JNB PSW.7, PLUS_NEXT_L

MOV A, R7

ADD A, #01H

DA A

MOV R7, A

PLUS_NEXT_L: MOV A, R2

MOV DPTR, #HI

MOVC A, @A+DPTR

ADD A, R7

DA A

MOV R7, A

AGAIN_L: MOV A, R0

RRC A

MOV R0, A

INC R2

CJNE R2, #08h, NACHALO_L

NACHALO_HI: MOV A, R1

JNB ACC.0, AGAIN_HI

MOV A, R2

MOV DPTR, #L

MOVC A, @A+DPTR

ADD A, R6

DA A

MOV R6, A

JNB PSW.7, PLUS_NEXT_HI

MOV A, R7

ADD A, #01H

DA A

MOV R7, A

PLUS_NEXT_HI: MOV A, R2

MOV DPTR, #HI

MOVC A, @A+DPTR

ADD A, R7

DA A

MOV R7, A

AGAIN_HI: MOV A, R1

RRC A

MOV R1, A

INC R2

CJNE R2, #0Dh, NACHALO_HI

MOV A, R6

MOV DPTR, #0B000h; Вывод на индикацию

MOVX @DPTR, A; младшей части кода

MOV A, R7

MOV DPTR, #0A000h; Вывод на индикацию

MOVX @DPTR, A; старшей части кода

RET

END

Варианты индивидуальных заданий

Таблица 10 Таблица заданий к л.р. №6